Add support for Dell EMC Isilon backend

This change adds a new define for manila::backend::dellemc_isilon,
allowing users to create multiple backend definitions within their puppet
manifests for use with Manila.

Change-Id: Iad810afb8ce0f42ee0ab200557483db4f0cff912
Closes-Bug: #1705330

manifests/backend/dellemc_isilon.pp

@@ -0,0 +1,93 @@
+# == define: manila::backend::dellemc_isilon
+#
+# Configures Manila to use the Dell EMC Isilon share driver
+# Compatible for multiple backends
+#
+# === Parameters
+#
+# [*driver_handles_share_servers*]
+#  (required) Denotes whether the driver should handle the responsibility of
+#   managing share servers. This must be set to false if the driver is to
+#   operate without managing share servers.
+#
+# [*emc_nas_login*]
+#   (required) Administrative user account name used to access the storage
+#   system.
+#
+# [*emc_nas_password*]
+#   (required) Password for the administrative user account specified in the
+#   emc_nas_login parameter.
+#
+# [*emc_nas_server*]
+#   (required) The hostname (or IP address) for the storage system.
+#
+# [*emc_share_backend*]
+#   (required) Share backend.
+#   Defaults to http
+#
+# [*share_backend_name*]
+#   (optional) Name of the backend in manila.conf that
+#   these settings will reside in
+#
+# [*emc_nas_root_dir*]
+#   (optional) The root directory where shares will be located.
+#   Defaults to None
+#
+# [*emc_nas_server_port*]
+#   (optional)  Port number for the Dell EMC isilon server.
+#   Defaults to 8080
+#
+# [*emc_nas_server_secure*]
+#   (optional) Use secure connection to server.
+#   Defaults to true
+#
+# [*package_ensure*]
+#   (optional) Ensure state for package. Defaults to 'present'.
+#
+# === Examples
+#
+#  manila::backend::dellemc_isilon { 'myBackend':
+#    driver_handles_share_servers  => false,
+#    emc_nas_login                 => 'admin',
+#    emc_nas_password              => 'password',
+#    emc_nas_server                => <IP address of isilon cluster>,
+#    emc_share_backend             => 'isilon',
+#  }
+#
+define manila::backend::dellemc_isilon (
+  $driver_handles_share_servers,
+  $emc_nas_login,
+  $emc_nas_password,
+  $emc_nas_server,
+  $emc_share_backend,
+  $share_backend_name        = $name,
+  $emc_nas_root_dir          = undef,
+  $emc_nas_server_port       = 8080,
+  $emc_nas_server_secure     = true,
+  $package_ensure            = 'present',
+) {
+
+  include ::manila::deps
+
+  validate_string($emc_nas_password)
+
+  $dellemc_isilon_share_driver = 'manila.share.drivers.emc.driver.EMCShareDriver'
+
+  manila_config {
+    "${share_backend_name}/share_driver":                 value => $dellemc_isilon_share_driver;
+    "${share_backend_name}/driver_handles_share_servers": value => $driver_handles_share_servers;
+    "${share_backend_name}/emc_nas_login":                value => $emc_nas_login;
+    "${share_backend_name}/emc_nas_password":             value => $emc_nas_password, secret => true;
+    "${share_backend_name}/emc_nas_server":               value => $emc_nas_server;
+    "${share_backend_name}/share_backend_name":           value => $share_backend_name;
+    "${share_backend_name}/emc_share_backend":            value => $emc_share_backend;
+    "${share_backend_name}/emc_nas_root_dir":             value => $emc_nas_root_dir;
+    "${share_backend_name}/emc_nas_server_port":          value => $emc_nas_server_port;
+    "${share_backend_name}/emc_nas_server_secure":        value => $emc_nas_server_secure;
+  }
+
+  ensure_resource('package','nfs-utils',{
+    ensure => $package_ensure,
+    tag    => 'manila-support-package',
+  })
+}

releasenotes/notes/isilon-driver-1409cf7661e3438.yaml

@@ -0,0 +1,3 @@
+---
+features:
+  - Add support for Dell EMC Isilon Driver

spec/defines/manila_backend_dellemc_isilon_spec.rb

@@ -0,0 +1,66 @@
+require 'spec_helper'
+
+describe 'manila::backend::dellemc_isilon' do
+
+  let(:title) {'dellemc_isilon'}
+
+  let :params do
+    {
+      :driver_handles_share_servers         => false,
+      :emc_nas_login                        => 'admin',
+      :emc_nas_password                     => 'password',
+      :emc_nas_server                       => '127.0.0.2',
+      :emc_share_backend                    => 'isilon',
+      :emc_nas_root_dir                     => '',
+    }
+  end
+
+  let :default_params do
+    {
+      :emc_nas_server_port           => 8080,
+      :emc_nas_server_secure         => true,
+    }
+  end
+
+  shared_examples_for 'dell emc isilon share driver' do
+    let :params_hash do
+      default_params.merge(params)
+    end
+
+    it 'configures dell emc isilon share driver' do
+      is_expected.to contain_manila_config("dellemc_isilon/share_driver").with_value(
+        'manila.share.drivers.emc.driver.EMCShareDriver')
+      params_hash.each_pair do |config,value|
+        is_expected.to contain_manila_config("dellemc_isilon/#{config}").with_value( value )
+      end
+    end
+
+    it 'marks emc_nas_password as secret' do
+      is_expected.to contain_manila_config("dellemc_isilon/emc_nas_password").with_secret( true )
+    end
+  end
+
+
+  context 'with default parameters' do
+    before do
+      params = {}
+    end
+
+    it_configures 'dell emc isilon share driver'
+  end
+
+  context 'with provided parameters' do
+    it_configures 'dell emc isilon share driver'
+  end
+
+  context 'with share server config' do
+    before do
+      params.merge!({
+        :emc_nas_password => true,
+      })
+    end
+
+    it { is_expected.to raise_error(Puppet::Error, /true is not a string.  It looks to be a TrueClass/) }
+  end
+
+end